大数据入门08-HIVE常用DDL操作

创建数据库

• 创建一个数据库，数据库在 HDFS 上的默认存储路径是/user/hive/warehouse/*.db。

create database db_hive; 

• 避免要创建的数据库已经存在错误，增加 if not exists 判断。（标准写法）

create database if not exists db_hive; 

• 创建一个数据库，指定数据库在 HDFS 上存放的位置

create database db_hive2 location '/db_hive2.db'; 

修改数据库

用户可以使用 ALTER DATABASE 命令为某个数据库的 DBPROPERTIES 设置键-值对
属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数
据库名和数据库所在的目录位置。

alter database db_hive set dbproperties('createtime'='20190101'); 

查询数据库

查看数据库详情

• 显示数据库信息

desc database db_hive; 

• 显示数据库详细信息，extended

desc database extended db_hive; 

切换当前数据库

use db_hive; 

删除数据库

• 删除空数据库

drop database db_hive2;

• 如果删除的数据库不存在，最好采用 if exists 判断数据库是否存在

drop database if exists db_hive2; 

• 如果数据库不为空，可以采用 cascade 命令，强制删除

drop database db_hive cascade; 

创建表

建表语法:

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name  
[(col_name data_type [COMMENT col_comment], ...)]  
[COMMENT table_comment]  
[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]  
[CLUSTERED BY (col_name, col_name, ...)  
[SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS]  
[ROW FORMAT row_format]  
[STORED AS file_format]  
[LOCATION hdfs_path] 

• CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出
  异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。
• EXTERNAL 关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际
  数据的路径（LOCATION），Hive 创建内部表时，会将数据移动到数据仓库指向的路
  径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的
  时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。
• COMMENT：为表和列添加注释。
• PARTITIONED BY 创建分区表
• CLUSTERED BY 创建分桶表
• SORTED BY 不常用

• ROW FORMAT
  DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]
  [MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]
  | SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, …)]
  用户在建表的时候可以自定义 SerDe 或者使用自带的 SerDe。如果没有指定 ROW FORMAT 或者 ROW FORMAT DELIMITED，将会使用自带的 SerDe。在建表的时候，
  用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的 SerDe，Hive 通过 SerDe 确定表的具体的列的数据。
  SerDe是Serialize/Deserilize的简称，目的是用于序列化和反序列化。

• STORED AS 指定存储文件类型
  常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、
  RCFILE（列式存储格式文件）
  如果文件数据是纯文本，可以使用 STORED AS TEXTFILE。如果数据需要压缩，
  使用 STORED AS SEQUENCEFILE。

• LOCATION ：指定表在 HDFS 上的存储位置.

• LIKE 允许用户复制现有的表结构，但是不复制数据.

管理表(内部表)

默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive 会（或多
或少地）控制着数据的生命周期。Hive 默认情况下会将这些表的数据存储在由配置项
hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。 当我们
删除一个管理表时，Hive 也会删除这个表中数据。管理表不适合和其他工具共享数据。

• 普通创建表

create table if not exists student2( id int, name string ) 
row format delimited fields terminated by '\t' 
stored as textfile 
location '/user/hive/warehouse/student2'; 

• 根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 
as select id, name from student; 

• 根据已经存在的表结构创建表

create table if not exists student4 like student; 

• 查询表的类型

desc formatted student2; 

外部表

• 建表语句
  创建部门表

  create external table if not exists default.dept( 
      deptno int, 
      dname string, 
      loc int ) 
      row format delimited fields terminated by '\t'; 

  创建员工表

create external table if not exists default.emp( 
    empno int, 
    ename string, 
    job string, 
    mgr int, 
    hiredate string,  
    sal double,  
    comm double, 
    deptno int) 
    row format delimited fields terminated by '\t'; 

• 向外部表中导入数据

load data local inpath '/opt/module/datas/dept.txt' into table default.dept;
load data local inpath '/opt/module/datas/emp.txt' into table default.emp; 

查询结果

select * from emp; 
select * from dept; 

• 查看表格式化数据

desc formatted dept; 

管理表与外部表的互相转换

• 修改内部表student2为外部表

alter table student2 set tblproperties('EXTERNAL'='TRUE');

• 查询表的类型

desc formatted student2;

• 修改外部表student2为内部表

alter table student2 set tblproperties('EXTERNAL'='FALSE');

分区表

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹，该文件夹下是该分区
所有的数据文件。Hive 中的分区就是分目录，把一个大的数据集根据业务需要分割成小的
数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区，这样的查
询效率会提高很多。
因为表是外部表，所以 Hive 并非认为其完全拥有这份数据。删除该表并不会删除掉这
份数据，不过描述表的元数据信息会被删除掉。

• 创建分区表

create table dept_partition( 
deptno int, 
dname string, 
loc string ) 
partitioned by (month string) 
row format delimited fields terminated by '\t'; 

• 加载数据到分区表中

load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201809');
load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201808');
load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201807');

• 查询分区表中数据

单分区查询

select * from dept_partition where month='201809';

多分区联合查询

select * from dept_partition where month='201809'
union
select * from dept_partition where month='201808'
union
select * from dept_partition where month='201807';

• 增加分区

增加单个分区

alter table dept_partition add partition(month='201806');

增加多个分区

alter table dept_partition add partition(month='201805') partition(month='201804');

• 删除分区

删除单个分区

alter table dept_partition drop partition (month='201804'); 

同时删除多个分区

alter table dept_partition drop partition (month='201805'), partition 
(month='201806'); 

这里需要注意的是删除多个分区是以” , “ 分割，而增加多个分区是以空格分割。

• 查看分区表有多少分区

show partitions dept_partition; 

• 查看分区表结构

desc formatted dept_partition; 

修改表

重命名表

语法：

ALTER TABLE table_name RENAME TO new_table_name 

增加/修改/替换列信息

• 语法

更新列

ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name] 

增加和替换列

ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...) 

ADD 是代表新增一字段，字段位置在所有列后面(partition 列前)，REPLACE 则是
表示替换表中所有字段。

---